/* This creates the nominal aggregate exchange rate*/
/* THIS HAS BEEN CORRECTED USING PCT CHG NORMALIZATION instead of levels normalization*/
/* created by TLM 4.25.05 */
/* modified for C:\Workdocs\Hellerstein\CI\post-FOMC\exchange rates\aggregate xrate 5.10.05 */

clear
set more off
#delimit;

tempfile tempxrate tempvolume;

use "C:\Workdocs\Hellerstein\CI\post-FOMC\exchange rates\nxrate stuff.dta", clear;

     drop date;
     gen date= yq(year, quarter);
     format date %tq;
     tsset date, quarterly;

     foreach i of varlist  nerargent - nerukingdom {;
        gg pctcg`i'= (`i' - l1.`i')/l1.`i';
        *order date pctcg`i' `i';
        drop `i';
        };
     reshape long pctcgner, i(year quarter date) j(ctry) string;

     label variable pctcgner "pct chg in FC/US$";
     sort date;
     sort ctry year quarter;
     save "`tempxrate'", replace;

use "C:\Workdocs\Hellerstein\CI\post-FOMC\exchange rates\sic_man new.dta", clear;

    renpfix importshare volume;

    reshape long volume, i(naics sic year) j(ctry) string;

    *dropping petroluem!;
    drop if sic==29;
    note _dta:  petroleum products have been dropped from shares;

    collapse (sum) volume, by(ctry year);
    label variable volume "total for country year combo over naics cats";
    bysort year: egen yrtotal= sum(volume);
    label variable yrtotal "total for all countries for year";

    gg import_share= volume/yrtotal;
    label variable import_share "ctry share in total imports for year i";
    bysort year: egen check= sum(import_share);
    assert check<=1.01 & check>=0.99;
    drop check;
    sort ctry year;
    save "`tempvolume'", replace;
    
    use "`tempxrate'", clear;
    merge ctry year using "`tempvolume'";
    assert _merge==3;
    drop _merge;

    bysort date: egen pctcgshare= sum(import_share * pctcgner);
    * we are collapsing over countries;
    collapse (mean) pctcgshare, by(date);
    drop if date<q(1980q1);
    gen pctcgxrate=100 in 1;
    replace pctcgxrate= (1 + pctcgshare)*l1.pctcgxrate in 2/l;

    label variable pctcgxrate "nominal import-weighted non-oil xrate";
    notes pctcgxrate:  this is based on the percent change method dropping no one.;
    notes _dta: created by TLM on TS from
         "C:\Workdocs\Hellerstein\CI\post-FOMC\exchange rates\aggregate xrate\create quarterly pct chg nxrate.do";
    notes _dta: based on yearly import volume weights;
    
    sort date;
    tsset;
    save "C:\Workdocs\Hellerstein\CI\post-FOMC\exchange rates\aggregate xrate\quarterly nominal xrate pctchg.dta", replace;